*FMMT619 Spice model
*SIMULATOR=SIMETRIX
*ORIGIN=PH
*DATE=09April2019
*VERSION=2
*#SIMETRIX
.Model FMMT619 NPN ; ## Description ## ## Effect ##
; ## DC Forward Parameters ##
+ IS = 5.8032E-13 ; transport saturation current Controls Icbo and where hFE falls with high Ic
+ NF = 1.02 ; forward current emission coefficient
+ ISE = 1.5933E-13 ; base-emitter leakage saturation current Controls the fall in hFE that occurs at low Ic
+ NE = 1.4148 ; base-emitter leakage emission coefficient Controls Icbo and where hFE falls with high Ic. Controls the fall in hFE that occurs at low Ic
+ BF = 465 ; ideal maximum forward beta Controls peak forward hFE
+ IKF = 8 ; corner for forward-beta high-current roll-off Current where rollof occurs
+ NK = 0.8 ; high-current roll-off coefficient Slope of roll off
+ VAF = 84 ; forward Early voltage controls the variation of collector current with voltage when the transistor is operated in its linear region.
; ## DC Reverse Parameters ##
+ NR = 1.0006 ; reverse current emission coefficient
+ ISC = 5E-12 ; base-collector leakage saturation current Controls the fall of reverse hFE at low currents
+ NC = 1.6 ; base-collector leakage emission coefficient Controls the fall of reverse hFE at low currents
+ BR = 110 ; ideal maximum reverse beta Controls peak reverse hFE
+ IKR = 1.4 ; corner for reverse-beta high-current roll-off Current where rollof occurs
+ VAR = 51 ; reverse Early voltage the reverse version of VAF.
; ## DC Rb Parameters ##
+ RB = 14.5 ; zero-bias (maximum) base resistance
+ IRB = 8.00E-06 ; current at which Rb falls halfway to RBM
+ RBM = 0.2 ; minimum base resistance
; ## DC Re Parameters ##
+ RE = 0.05 ; emitter ohmic resistance
; ## DC Rc Parameters ##
+ RC = 0.0375 ; collector ohmic resistance
; ## AC base-emitter Parameters ##
+ CJE= 2.17E-10 ; base-emitter zero-bias p-n capacitance controls Cbe.
+ VJE = 0.75 ; base-emitter built-in potential
+ MJE = 0.33 ; base-emitter p-n grading factor
; ## AC base-collector Parameters ##
+ CJC = 4E-11 ; base-collector zero-bias p-n capacitance control Ccb and how it varies with Vcb.
+ VJC = 0.4347 ; base-collector built-in potential control Ccb and how it varies with Vcb.
+ MJC = 0.3708 ; base-collector p-n grading factor control Ccb and how it varies with Vcb.
+ XCJC = 1 ; fraction of CJC connected internally to Rb
; ## AC substrate Parameters ##
+ CJS = 0 ; substrate zero-bias p-n capacitance
+ VJS = 0.75 ; substrate p-n built-in potential
+ MJS = 0 ; substrate p-n grading factor
; ## AC Transit Time Parameters ##
+ TF = 780.0E-12 ; ideal forward transit time controls Ft and switching speeds.
+ XTF = 0 ; transit time bias dependence coefficient
+ VTF = 1E+20 ; transit time dependency on Vbc
+ ITF = 0 ; transit time dependency on Ic
+ PTF = 0 ; excess phase @ 1/(2p·TF)Hz
+ TR = 9.00E-09 ; ideal reverse transit time controls switching storage times.
; ##Temperature Parameters ##
+ XTB = 1.3 ; forward and reverse beta temperature coefficient controls temperature effects on hFE. Try 1.6 for NPN, 1.9 for PNP
+ XTI = 3 ; IS temperature effect exponent controls temperature effects on saturation current
+ RCO = 0 ; epitaxial region resistance
+ TRB1 = 0 ; RB temperature coefficient (linear)
+ TRB2 = 0 ; RB temperature coefficient (quadratic)
+ TRC1 = 0 ; RC temperature coefficient (linear)
+ TRC2 = 0 ; RC temperature coefficient (quadratic)
+ TRE1 = 0 ; RE temperature coefficient (linear)
+ TRE2 = 0 ; RE temperature coefficient (quadratic)
+ TRM1 = 0 ; RBM temperature coefficient (linear)
+ TRM2 = 0 ; RBM temperature coefficient (quadratic)
* T_ABS = ; absolute temperature
+ T_MEASURED = 27 ; measured temperature
* T_REL_GLOBAL = ; relative to current temperature
+ QUASIMOD = 1 ; quasi-saturation model flag for temperature dependence 1= Gamma, RCO, VO temp dependance 0n. 0=off.
+ CN = 2.42 ; quasi-saturation temperature coefficient for hole mobility defaults NPN 2.42, PNP 2.20
+ D = 0.87 ; quasi-saturation temperature coefficient -hole carrier velocity defaults NPN 0.87, PNP 0.52
+ FC = 0.5 ; forward-bias depletion capacitor coefficient
+ EG = 1.11 ; bandgap voltage (barrier height)
+ GAMMA = 1E-11 ; epitaxial region doping factor
+ ISS = 0 ; substrate p-n saturation current
+ NS = 1 ; substrate p-n emission coefficient
+ QCO = 0 ; epitaxial region charge factor
; ## Flicker Parameters ##
+ AF = 1 ; flicker noise exponent
+ KF = 0 ; flicker noise coefficient 0.0
+ VG = 1.206 ; quasi-saturation extrapolated bandgap voltage at 0° K
+ VO = 10 ; carrier mobility knee voltage
* (c) 2019 Diodes Inc
*
* The copyright in these models and the designs embodied belong
* to Diodes Incorporated (" Zetex "). They are supplied
* free of charge by Zetex for the purpose of research and design
* and may be used or copied intact (including this notice) for
* that purpose only. All other rights are reserved. The models
* are believed accurate but no condition or warranty as to their
* merchantability or fitness for purpose is given and no liability
* in respect of any use is accepted by Diodes Incorporated, its distributors
* or agents.
*
* Diodes Zetex Semiconductors Ltd, Zetex Technology Park, Chadderton,
* Oldham, United Kingdom, OL9 9LL